pxGetBodyEntity%(body%)

Параметры

body% - физическое тело

Описание

Возвращает меш блица принадлежащий физическому телу

Смотрите так же

    Команды установки параметров:
pxSetBodyEntity
    Команды группы:
pxGetBodyName, pxGetBodyUserData, pxSetBodyName, pxSetBodyUserData

Пример

;Пример применения функции
;pxGetBodyEntity

;в примере нам понадобится несколько однотипных тел
Type Px_Cylinder
    Field body%
End Type

Graphics3D 800, 600, 32, 2
SetBuffer BackBuffer()

;Создаем физический мир, устанавливаем гравитацию.
pxCreateWorld(1) ;У нас будет поверхность
pxSetGravity(0, -10, 0)

camera=CreateCamera()
light=CreateLight()

PositionEntity camera,0,20,-40
RotateEntity camera,30,0,0

plane=CreatePlane() ;Визуализируем поверхность
EntityColor plane,0,100,200
EntityAlpha plane,0.5

mir = CreateMirror () ;Чуть украсим зеркалом

;Добавим объектов к сцене
For n = 1 to 40

    mesh = CreateCylinder() ;Создаем визуальное отображение
    ScaleEntity mesh,1,3,1 ;зададим размер
    EntityColor mesh,Rand(0,255), Rand(0,255), Rand(0,255) ;и цвет
;Устанавливаем пик мыша на тело
    EntityPickMode mesh,2

    ocu.Px_Cylinder = New Px_Cylinder
    ocu\body=pxCreateCylinder( 1, 3, 8, 1) ;Создаем физический объект
    pxSetPosition(ocu\body,Rand(-20,20),40,Rand(-10,30)) ;размещаем случайным образом
    pxSetRotation(ocu\body,Rand(-50,50),Rand(-50,50),Rand(-50,50))

    pxSetBodyEntity(ocu\body,mesh) ;Присвоим телу меш
    pxSetBodyName(ocu\body,"Цилиндр № "+n) ;Присвоим телу имя
    pxSetBodyUserData(ocu\body,n) ;Присвоим телу номер
; pxSetBodyUserData(ocu\body,ocu.Px_Cylinder) ;Присвоим телу данные о теле

Next
;Создаем вектор райпик для тестирования наличия объектов
ray = pxCreateRay()
pxRaySetDir(ray, 0,-1,0) ;Пусть будет пик в верх

;Основной цикл программы
While Not KeyDown(1) ;Пока не нажат ESC

;обсчитываем физический мир
    RenderPhysic(60,0)

;Обновим положения всех объектов
    For ocu.Px_Cylinder = Each Px_Cylinder
;----------- применяем pxGetBodyEntity: ------------
     pxSetEntity(pxGetBodyEntity(ocu\body), ocu\body)
    Next

;UpdateWorld

    RenderWorld

;Если нажат левый мыш
; If MouseHit(1) Then
    If MouseDown(1) Then
        ent=CameraPick(camera,mouseX(),MouseY()) ; проверяем куда он попал
        If ent Then ;Попали на меш блица
            pxRaySetPosition ray, PickedX(),PickedY(),PickedZ()
            body = pxRayGetBody(ray ,1) ;получаем физическое тело
;пнем в верх
            If body Then
;pxAddForce(body, 0,200,0, 0)
                Text 10,10, "Имя пикнутого тела "+pxGetBodyName(body)
                Text 10,20, "его номер "+pxGetBodyUserData(body)
            EndIf
        Else
            Text 10,10, "Желательно попасть в тело"
        EndIf
    Else
        Text 10,10, "Тела пикаются мышю"
    EndIf

    Flip
    Wend

End

К содержанию

Нажмите здесь чтобы увидеть последнюю версию этой странички в режиме online.